# ==========================================================================
#         ____            _                     _____           _
#        / ___| _   _ ___| |_ ___ _ __ ___     |_   _|__   ___ | |___
#        \___ \| | | / __| __/ _ \ '_ ` _ \ _____| |/ _ \ / _ \| / __|
#         ___) | |_| \__ \ ||  __/ | | | | |_____| | (_) | (_) | \__ \
#        |____/ \__, |___/\__\___|_| |_| |_|     |_|\___/ \___/|_|___/
#               |___/
#                             --- System-Tools ---
#                  https://www.nntb.no/~dreibh/system-tools/
# ==========================================================================
#
# System-Tools
# Copyright (C) 2013-2026 by Thomas Dreibholz
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
#
# Contact: dreibh@simula.no


CMAKE_MINIMUM_REQUIRED(VERSION 3.10)
PROJECT(td-system-tools)
ENABLE_LANGUAGE(C)

SET(BUILD_MAJOR "2")
SET(BUILD_MINOR "7")
SET(BUILD_PATCH "4")
SET(BUILD_VERSION ${BUILD_MAJOR}.${BUILD_MINOR}.${BUILD_PATCH})


#############################################################################
#### CMAKE INCLUDES                                                      ####
#############################################################################

INCLUDE(CheckCCompilerFlag)
INCLUDE(CheckCSourceCompiles)
INCLUDE(CheckCSourceRuns)
INCLUDE(CheckIncludeFile)
INCLUDE(CheckStructHasMember)
INCLUDE(GNUInstallDirs)


#############################################################################
#### PACKAGING                                                           ####
#############################################################################

SET(CPACK_SOURCE_GENERATOR "TXZ")
SET(CPACK_SOURCE_PACKAGE_FILE_NAME
    "${CMAKE_PROJECT_NAME}-${BUILD_MAJOR}.${BUILD_MINOR}.${BUILD_PATCH}")
SET(CPACK_SOURCE_IGNORE_FILES "\\\\.git;\\\\.swp$;~$;\\\\.\\\\#;/\\\\#")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "^${PROJECT_SOURCE_DIR}/${CMAKE_PROJECT_NAME}[_-]")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "\\\\.make$|\\\\.log$")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "/CMakeCache\\\\.txt$")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "/(CMakeFiles|CMakeScripts|_CPack_Packages)/")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "/package-version\\\\.h$")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "/packaging\\\\.conf$")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "^${PROJECT_SOURCE_DIR}/(po.*/|src.*/|)Makefile$")
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "^${PROJECT_SOURCE_DIR}/(po.*|src.*|[^/]*)\\\\.cmake$")

# Do not pack the example figures used for the README.md documentation
# (need to be in the repository, but are generated by script make-figures).
LIST(APPEND CPACK_SOURCE_IGNORE_FILES "^${PROJECT_SOURCE_DIR}/src/GIMP-Scripts/figures")

INCLUDE(CPack)

ADD_CUSTOM_TARGET(dist COMMAND ${CMAKE_MAKE_PROGRAM} clean package_source)


#############################################################################
#### UNINSTALL                                                           ####
#############################################################################

IF(NOT TARGET uninstall)
   CONFIGURE_FILE(
      "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
      "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
      IMMEDIATE @ONLY)

   ADD_CUSTOM_TARGET(uninstall
      COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
ENDIF()


#############################################################################
#### OS DEPENDENT                                                        ####
#############################################################################

IF (CMAKE_SYSTEM_NAME MATCHES "Linux")
   MESSAGE(STATUS "${CMAKE_SYSTEM_NAME} supported")
ELSEIF (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
   MESSAGE(STATUS "${CMAKE_SYSTEM_NAME} supported")
ELSEIF (CMAKE_SYSTEM_NAME MATCHES "NetBSD")
   MESSAGE(STATUS "${CMAKE_SYSTEM_NAME} supported")
ELSEIF (CMAKE_SYSTEM_NAME MATCHES "OpenBSD")
   MESSAGE(STATUS "${CMAKE_SYSTEM_NAME} supported")
ELSEIF (CMAKE_SYSTEM_NAME MATCHES "Darwin")
   MESSAGE(STATUS "${CMAKE_SYSTEM_NAME} supported")
ELSE()
   MESSAGE(FATAL_ERROR "${CMAKE_SYSTEM_NAME} not supported (yet?)")
ENDIF()


#############################################################################
#### OPTIONS                                                             ####
#############################################################################

OPTION(WITH_I18N "Build with Internationalization (i18n) support"           ON)

OPTION(WITH_SYSTEM_INFO                "Include System-Info"                ON)
OPTION(WITH_SYSTEM_INFO_DEFAULT_BANNER "Include System-Info Default Banner" ON)
OPTION(WITH_SYSTEM_INFO_IN_PROFILES    "Include System-Info in Profiles"    ON)
OPTION(WITH_SYSTEM_INFO_EXAMPLES       "Include System-Info Examples"       ON)

OPTION(WITH_GET_SYSTEM_INFO            "Include get-system-info"            ON)
OPTION(WITH_SYSTEM_MAINTENANCE         "Include System-Maintenance"         ON)
OPTION(WITH_PRINT_UTF8                 "Include Print-UTF8"                 ON)
OPTION(WITH_TEXT_BLOCK                 "Include Text-Block"                 ON)
OPTION(WITH_FINGERPRINT_SSH_KEYS       "Include Fingerprint-SSH-Keys"       ON)
OPTION(WITH_CONFIGURE_GRUB             "Include Configure-GRUB"             ON)
OPTION(WITH_RESET_MACHINE_ID           "Include Reset-Machine-ID"           ON)
OPTION(WITH_TRY_HARD                   "Include Try-Hard"                   ON)
OPTION(WITH_RANDOM_SLEEP               "Include Random-Sleep"               ON)
OPTION(WITH_UNIX_TIMESTAMP_TOOLS       "Include Unix-Timestamp Tools"       ON)
OPTION(WITH_X509_TOOLS                 "Include X.509 Tools"                ON)
OPTION(WITH_GIMP_SCRIPTS               "Include GIMP-Scripts"               ON)
OPTION(WITH_GIMP_SCRIPTS_EXAMPLES      "Include GIMP-Scripts Examples"      ON)

IF (WITH_SYSTEM_INFO AND NOT (WITH_GET_SYSTEM_INFO AND WITH_PRINT_UTF8))
   MESSAGE(FATAL_ERROR "WITH_SYSTEM_INFO requires WITH_GET_SYSTEM_INFO and WITH_PRINT_UTF8!")
ENDIF()
IF (WITH_SYSTEM_INFO_IN_PROFILES AND NOT WITH_SYSTEM_INFO)
   MESSAGE(FATAL_ERROR "WITH_SYSTEM_INFO_IN_PROFILES requires WITH_SYSTEM_INFO!")
ENDIF()
IF (WITH_SYSTEM_INFO_DEFAULT_BANNER AND NOT WITH_SYSTEM_INFO)
   MESSAGE(FATAL_ERROR "WITH_SYSTEM_INFO_DEFAULT_BANNER requires WITH_SYSTEM_INFO!")
ENDIF()
IF (WITH_SYSTEM_INFO_EXAMPLES AND NOT WITH_SYSTEM_INFO)
   MESSAGE(FATAL_ERROR "WITH_SYSTEM_INFO_EXAMPLES requires WITH_SYSTEM_INFO!")
ENDIF()

IF (WITH_TRY_HARD AND NOT WITH_RANDOM_SLEEP)
   MESSAGE(FATAL_ERROR "WITH_TRY_HARD requires WITH_RANDOM_SLEEP!")
ENDIF()

IF (WITH_X509_TOOLS AND NOT (WITH_PRINT_UTF8 AND WITH_TEXT_BLOCK))
   MESSAGE(FATAL_ERROR "WITH_X509_TOOLS requires WITH_PRINT_UTF8 and WITH_TEXT_BLOCK!")
ENDIF()

IF (WITH_GIMP_SCRIPTS_EXAMPLES AND NOT WITH_GIMP_SCRIPTS)
   MESSAGE(FATAL_ERROR "WITH_GIMP_SCRIPTS_EXAMPLES requires WITH_GIMP_SCRIPTS!")
ENDIF()


#############################################################################
#### INTERNATIONALISATION (I18N)                                         ####
#############################################################################

IF (WITH_I18N)
   FIND_PACKAGE(Intl)
   IF (Intl_FOUND)
      MESSAGE(STATUS "Internationalization (i18n) support found:")
      MESSAGE(STATUS " Intl_INCLUDE_DIRS: ${Intl_INCLUDE_DIRS}")
      MESSAGE(STATUS " Intl_LIBRARIES:    ${Intl_LIBRARIES}")
      MESSAGE(STATUS " Version:           ${Intl_VERSION}")
   ELSE()
      MESSAGE(FATAL_ERROR
            "Cannot find Internationalization (i18n) support! Try:\n"
            " * Ubuntu/Debian: sudo apt install -y libc6-dev\n"
            " * Fedora:        sudo dnf install -y gettext-devel\n"
            " * SuSE:          sudo zypper install -y gettext-devel\n"
            " * Alpine:        sudo apk add gettext-dev\n"
            " * FreeBSD:       sudo pkg install -y gettext\n"
            " * NetBSD:        sudo pkgin -y install gettext\n"
            " * OpenBSD:       sudo pkg_add gettext-runtime gettext-tools\n"
            " * Apple:         brew install gettext")
   ENDIF()

   FIND_PROGRAM(XGETTEXT xgettext HINTS /usr/pkg/bin /opt/homebrew/opt/gettext/bin /usr/local/opt/gettext/bin)
   FIND_PROGRAM(MSGMERGE msgmerge HINTS /usr/pkg/bin /opt/homebrew/opt/gettext/bin /usr/local/opt/gettext/bin)
   FIND_PROGRAM(MSGFMT   msgfmt   HINTS /usr/pkg/bin /opt/homebrew/opt/gettext/bin /usr/local/opt/gettext/bin)

   IF (XGETTEXT AND MSGMERGE AND MSGFMT)
      MESSAGE(STATUS "GNU gettext support found:")

      EXECUTE_PROCESS(COMMAND ${XGETTEXT} --version
                      OUTPUT_VARIABLE XGETTEXT_OUTPUT
                      ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
      STRING(REGEX MATCH "([0-9]+\\.[0-9]+\\.[0-9]+|[0-9]+\\.[0-9]+)" XGETTEXT_VERSION "${XGETTEXT_OUTPUT}")

      EXECUTE_PROCESS(COMMAND ${MSGMERGE} --version
                      OUTPUT_VARIABLE MSGMERGE_OUTPUT
                      ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
      STRING(REGEX MATCH "([0-9]+\\.[0-9]+\\.[0-9]+|[0-9]+\\.[0-9]+)" MSGMERGE_VERSION "${MSGMERGE_OUTPUT}")

      EXECUTE_PROCESS(COMMAND ${MSGFMT} --version
                      OUTPUT_VARIABLE MSGFMT_OUTPUT
                      ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
      STRING(REGEX MATCH "([0-9]+\\.[0-9]+\\.[0-9]+|[0-9]+\\.[0-9]+)" MSGFMT_VERSION "${MSGFMT_OUTPUT}")

      MESSAGE(STATUS " xgettext: ${XGETTEXT} (version ${XGETTEXT_VERSION})")
      MESSAGE(STATUS " msgmerge: ${MSGMERGE} (version ${MSGMERGE_VERSION})")
      MESSAGE(STATUS " msgfmt:   ${MSGFMT} (version ${MSGFMT_VERSION})")
   ENDIF()

   SET(GETTEXT_MIN_VERSION 0.19)
   IF ((NOT XGETTEXT) OR (NOT MSGMERGE) OR (NOT MSGFMT)       OR
       (XGETTEXT_VERSION VERSION_LESS ${GETTEXT_MIN_VERSION}) OR
       (MSGMERGE_VERSION VERSION_LESS ${GETTEXT_MIN_VERSION}) OR
       (MSGFMT_VERSION   VERSION_LESS ${GETTEXT_MIN_VERSION}))
      MESSAGE(FATAL_ERROR
              "Cannot find gettext tools >= ${GETTEXT_MIN_VERSION}! Try:\n"
              " * Ubuntu/Debian: sudo apt install -y gettext\n"
              " * Fedora:        sudo dnf install -y gettext\n"
              " * SuSE:          sudo zypper install -y gettext\n"
              " * Alpine:        sudo apk add gettext-dev\n"
              " * FreeBSD:       sudo pkg install -y gettext-tools\n"
              " * NetBSD:        sudo pkgin -y install gettext-tools\n"
              " * OpenBSD:       sudo pkg_add gettext-tools\n"
              " * Apple:         brew install gettext")
   ENDIF()

   ADD_DEFINITIONS(-DENABLE_NLS)
ENDIF()


#############################################################################
#### SUBDIRECTORIES                                                      ####
#############################################################################

ADD_SUBDIRECTORY(src)

IF (WITH_I18N)
   ADD_SUBDIRECTORY(po)
ENDIF()
